DOS/V Power Report 1997 March/VPR9703B.ISO/driver/omron/6420dsu/mac/ara’è‹`/!omronfw.960

Text File | 1996-09-12 | 4KB | 261 lines

!
! "OMRON FW6420 9/12/96"
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 9600, 0, 8, 1
!
! first recall the factory configuration
!
hsreset 0 1 0 0 0 0
dtrclear
pause 10
dtrset
pause 10
matchclr
settries 0
matchstr 1 3 "OK\13\10"
@LABEL 2
write "ATZ\13"
matchread 30
inctries
iftries 2 59
jump 2
!
! Next, Set up the configuration: Echo off
!
@LABEL 3
matchstr 1 4 "OK\13\10"
write "ATE0\13"
matchread 30
jump 59
!
! Set result code is long form.
!
@LABEL 4
matchstr 1 5 "OK\13\10"
write "ATQ0V1\13"
matchread 30
jump 59
!
! Set RS-CS flow control
!
@LABEL 5
matchstr 1 6 "OK\13\10"
write "AT&K3\13"
matchread 30
jump 59
!
! Set the format of "connect xxxx" result code
!
@LABEL 6
matchstr 1 7 "OK\13\10"
write "ATX4\13"
matchread 30
jump 59
!
! Set the format of "RING" result code
!
@LABEL 7
matchstr 1 8 "OK\13\10"
write "ATW0\13"
matchread 30
jump 59
!
! Set not PPP mode
!
@LABEL 8
matchstr 1 9 "OK\13\10"
write "AT$N1=0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 9
note "FW6420 Ready"3
ifANSWER 30
!
! @ORIGINATE
!
note "Dialing ^1" 3
! localized note "Dialing ^1" 3
write "ATS0=0D^1\13"
!
@LABEL 10
matchstr  1 14 "CONNECT 9600\13\10"
matchstr  2 50 "NO CARRIER\13\10"
matchstr  3 51 "ERROR\13\10"
matchstr  4 53 "BUSY\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps" 3
! localized note "Communicating at 1200 bps" 3
jump 20
!
@LABEL 12
note "Communicating at 2400 bps" 3
! localized note "Communicating at 2400 bps" 3
jump 20
!
@LABEL 13
note "Communicating at 4800 bps" 3
! localized note "Communicating at 4800 bps" 3
jump 20
!
@LABEL 14
note "Communicating at 9600 bps" 3
! localized note "Communicating at 9600 bps" 3
jump 20
!
@LABEL 15
note "Communicating at 14400 bps" 3
! localized note "Communicating at 14400 bps" 3
jump 20
!
@LABEL 16
note "Communicating at 19200 bps" 3
! localized note "Communicating at 19200 bps" 3
jump 20
!
@LABEL 17
note "Communicating at 28800 bps" 3
! localized note "Communicating at 28800 bps" 3
jump 20
!
@LABEL 18
note "Communicating at 38400 bps" 3
! localized note "Communicating at 38400 bps" 3
jump 20
!
@LABEL 19
note "Communicating at 57600 bps" 3
! localized note "Communicating at 57600 bps" 3
jump 20
!
@LABEL 20
ifANSWER 21
pause 30
!
@LABEL 21
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
matchstr 1 31 "OK\13\10"
write "ATS0=1\13"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5  14 "CONNECT 9600\13\10"
matchstr 6  15 "CONNECT 14400\13\10"
matchstr 7  17 "CONNECT 19200\13\10"
matchstr 9  18 "CONNECT 38400\13\10"
matchstr 10 19 "CONNECT 57600\13\10"
matchstr 11 50 "NO CARRIER\13\10"
matchstr 12 51 "ERROR\13\10"
matchstr 13 53 "BUSY\13\10"
matchread 700
jump 59
!
@LABEL 32
userhook 1
note "Answering incoming call" 3
! localized note "Answering phoneﾉ" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 51
exit -6016
!
@LABEL 53
exit -6022
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
matchclr
matchstr 1 64 "OK\13\10"
!
@LABEL 61
pause 15
write "+++"
pause 15
matchread 15
inctries
! no response, try three times
iftries 3 62
jump 61
!
! No response from modem, toggle DTR
!
@LABEL 62
dtrclear
pause 10
dtrset
jump 63

@LABEL 63
note "If the ACT LED of FW6420 is light,push DISC key or hang up the line." 3

@LABEL 64
settries 0
matchclr
matchstr 1 66 "OK\13\10"
write "ATH\13"
matchread 15
inctries
iftries 3 66
jump 64
! no response, try three times!
!
!
dtrclear
pause 10
dtrset
pause 10
write "AT\13"
matchread 30
jump 66
matchstr 1 66 "OK\13\10"
!
@LABEL 66
flush
matchclr
matchstr 1 68 "OK\13\10"
!
! Recall the factory settings
!
@LABEL 67
write "ATZ\13"
matchread 30
jump 59
!
@LABEL 68
matchstr 1 69 "OK\13\10"
write "ATS0=0\13"
matchread 30
jump 59
!
@LABEL 69
exit 0